Agfdhyk

I'm having difficulties to find a way to add 1d array to a 2d array in VB. For example:

Dim arr(,) As Integer

arr = { {0, 1}, {2, 3}, {4, 5} }

arr{3} = {6, 7}

'Now arr should be = { {0, 1}, {2, 3}, {4, 5}, {6, 7} }

Note that the code above is just a demonstration on what I want to achieve, it doesn't work.

I have been trying things suggested on forum such as:

1. ReDim Preserve


2. Array.Resize


3. Making 2d loop to copy everysingle element to a new variable and add new element then ReDim it back to arr

All I tried, but they all doesn't seem to work. At the end of the day, I'm looking for a subroutine that could append an 2d array of unknown length for example:

Dim arr(,) As Integer

append(arr, {0, 1})

append(arr, {2, 3})

'Now arr should be = {{0, 1}, {2, 3}}

You need to Redim Preserve the array, but you cannot do that because it adds another column when you want another row. So you will have to define a new array and copy the data:

Public Sub Append2DRow(ByRef arr(,) As Integer, new_row(,) As Integer)

    Dim new_arr(,) As Integer

    ReDim new_arr(0 To UBound(arr, 1) + 1, 0 To 1)



    Array.Copy(arr, new_arr, arr.LongLength)



    new_arr(UBound(new_arr, 1), 0) = new_row(0, 0)

    new_arr(UBound(new_arr, 1), 1) = new_row(0, 1)



    arr = new_arr

End Sub



Public Sub Append1DRow(ByRef arr(,) As Integer, new_row() As Integer)

    Dim new_arr(,) As Integer

    ReDim new_arr(0 To UBound(arr, 1) + 1, 0 To 1)



    Array.Copy(arr, new_arr, arr.LongLength)



    new_arr(UBound(new_arr, 1), 0) = new_row(0)

    new_arr(UBound(new_arr, 1), 1) = new_row(1)



    arr = new_arr

End Sub

Dim arr(,) As Integer

arr = {{0, 1}, {2, 3}, {4, 5}}



Append2DRow(arr, {{6, 7}})

Append1DRow(arr, {6, 7})

You can avoid this problem by forcing yourself into having an array with two rows and variable number of columns, but then you won't be able to initialize it that easily and it will probably be more difficult to work with in general:

Public Sub Append2DRow(ByRef arr(,) As Integer, new_row(,) As Integer)

    ReDim Preserve arr(0 To 1, 0 To UBound(arr, 2) + 1)

    arr(0, UBound(arr, 2)) = new_row(0, 0)

    arr(1, UBound(arr, 2)) = new_row(0, 1)

End Sub



Public Sub Append1DRow(ByRef arr(,) As Integer, new_row() As Integer)

    ReDim Preserve arr(0 To 1, 0 To UBound(arr, 2) + 1)

    arr(0, UBound(arr, 2)) = new_row(0)

    arr(1, UBound(arr, 2)) = new_row(1)

End Sub

Dim arr(0 To 1, 0 To 2) As Integer

arr(0, 0) = 0 : arr(1, 0) = 1

arr(0, 1) = 2 : arr(1, 1) = 3

arr(0, 2) = 4 : arr(1, 2) = 5



Append2DRow(arr, {{6, 7}})

Append1DRow(arr, {6, 7})

However you should not use arrays for this to begin with. You should use lists:

Dim list = New List(Of Integer()) From {

    New Integer() {0, 1},

    New Integer() {2, 3},

    New Integer() {4, 5}

}



list.Add({6, 7})